ReAPI Flash Control 1.1

#include <amxmodx>
#include <reapi>
#if AMXX_VERSION_NUM < 183
    #include <colorchat>
#endif

#define NO_FLASH_ACCESS ADMIN_LEVEL_H    // Флаг для антифлеша. Если нужно чтобы не слепило всю команду - закомментируйте

public plugin_init()
{
    register_plugin("[reAPI] Flash Control", "1.1", "neugomon");

    RegisterHookChain(RG_PlayerBlind, "fwdPlayerBlindPre", false);
}

#if defined NO_FLASH_ACCESS
new bool:g_bNoFlash[33];
public client_putinserver(id)
    g_bNoFlash[id] = bool:(get_user_flags(id) & NO_FLASH_ACCESS);
#endif
public fwdPlayerBlindPre(const id, const inflictor, const attacker)
{
    if(id == attacker)
        return HC_CONTINUE;
    if(get_member(id, m_iTeam) != get_member(attacker, m_iTeam))
        return HC_CONTINUE;
    if(is_user_alive(id))
    {
        static sFlasherName[32]; get_user_name(attacker, sFlasherName, charsmax(sFlasherName));
        client_print_color(id, print_team_default, "^1[^4Flash Control^1] ^4Вас хотел ослепить ^3криворукий ^4тиммейт ^3%s", sFlasherName);
    }
#if defined NO_FLASH_ACCESS
    return g_bNoFlash[id] ? HC_SUPERCEDE : HC_CONTINUE;
#else
    return HC_SUPERCEDE;
#endif
}